Wolfram Language & System Documentation Center

ParallelAxisPlot

ParallelAxisPlot[{{y₁₁,…,y_1n},…,{y_m1,…,y_mn}}]

generates a parallel axis plot for the points {y_i1,…,y_in} using equally spaced axes.

ParallelAxisPlot[{data₁,data₂,…}]

plots several sets of points.

Details and Options

ParallelAxisPlot is also known as parallel coordinate plot and profile graph.
ParallelAxisPlot displays an -dimensional point by drawing a line through the coordinate values on parallel axes. Lines that are close together indicate that the points are close together.

The data values y_i can be given in the following forms:
y_i a real-valued number

Quantity[y_i,unit] a quantity with a unit
Values y_i that are not of the forms shown previously are taken to be missing and are not shown.
The data_i have the following forms and interpretations:

	<\|"k₁"y₁,"k₂"y₂,…\|>	values {y₁,y₂,…}
	{y₁"lbl₁",y₂"lbl₂",…}, {y₁,y₂,…}{"lbl₁","lbl₂",…}	values {y₁,y₂,…} with labels {lbl₁,lbl₂,…}
	SparseArray	values as a normal array
	TimeSeries,EventSeries,…	values from time series data
	QuantityArray	magnitudes
	WeightedData	unweighted values

ParallelAxisPlot[Tabular[…]cspec] extracts and plots values from the tabular object using the column specification cspec.
The following forms of column specifications cspec are allowed for plotting tabular data:
{col_y1,…,col_yn} plot each column col_yi on its own axis
The following wrappers can be used:

	Annotation[data_i,label]	provide an annotation for the data
	Button[data_i,action]	define an action to execute when the data is clicked
	Callout[data_i,label]	label the data with a callout
	Callout[data_i,label,pos]	place the callout at relative position pos
	EventHandler[data_i,events]	define a general event handler for the data
	Hyperlink[data_i,uri]	make the data a hyperlink
	Labeled[data_i,label]	label the data
	Labeled[data_i,label,pos]	place the label at relative position pos
	Legended[data_i,label]	identify the data in a legend
	PopupWindow[data_i,cont]	attach a popup window to the data
	StatusArea[data_i,label]	display in the status area on mouseover
	Style[data_i,styles]	show the data using the specified styles
	Tooltip[data_i,label]	attach a tooltip to the curve

Wrappers w can be applied at multiple levels:
w[{y₁,…,y_n}] wrap a point

w[{data₁,…}] wrap a set of points data_i

w₁[w₂[…]] use nested wrappers
ParallelAxisPlot has the same options as Graphics, with the following additions and changes: [List of all options]

AspectRatio	1/GoldenRatio	ratio of height to width
Axes	True	whether to draw axes
ColorFunction	Automatic	how to determine the coloring of lines
ColorFunctionScaling	True	whether to scale arguments to ColorFunction
LabelingFunction	Automatic	how to label points
LabelingSize	Automatic	maximum size of callouts and labels
Mesh	None	whether to draw mesh points on each curve
MeshStyle	Automatic	the style for mesh points
PerformanceGoal	$PerformanceGoal	aspects of performance to try to optimize
PlotLegends	None	legends for lines
PlotMarkers	None	markers to use to indicate each point
PlotRange	All	range of values to include
PlotStyle	Automatic	graphics directives to determine the style of each line
PlotTheme	$PlotTheme	overall theme for the plot
ScalingFunctions	None	how to scale individual coordinates
TargetUnits	Automatic	units to display in the plot

The axes are arranged from left to right.
By default, each axis uses a plot range determined by the range of values along it.
PlotRangeAutomatic uses the same range for all the axes.
Options that apply to each axis, such as Axes, Ticks and PlotRange, can take the following forms:

	s	use setting s for each axis
	{s₁,…,s_n}	use per-axis setting s₁ for the first axis etc.
	{…,pats,…}	use setting s for axis positions matching pattern pat

With the form {…,pats,…}, pat can be any pattern. The first pattern that matches an axis position will be used. If no pattern matches an axis position, the default value is used.
The arguments supplied to ColorFunction are y₁,y₂,…,y_n. By default, the color function arguments are scaled per axis to be between 0 and 1.
ColorData["DefaultPlotColors"] gives the default sequence of colors used by PlotStyle.

List of all options

AlignmentPoint	Center	the default point in the graphic to align with
AspectRatio	1/GoldenRatio	ratio of height to width
Axes	True	whether to draw axes
AxesLabel	None	axes labels
AxesOrigin	Automatic	where axes should cross
AxesStyle	{}	style specifications for the axes
Background	None	background color for the plot
BaselinePosition	Automatic	how to align with a surrounding text baseline
BaseStyle	{}	base style specifications for the graphic
ColorFunction	Automatic	how to determine the coloring of lines
ColorFunctionScaling	True	whether to scale arguments to ColorFunction
ContentSelectable	Automatic	whether to allow contents to be selected
CoordinatesToolOptions	Automatic	detailed behavior of the coordinates tool
Epilog	{}	primitives rendered after the main plot
FormatType	TraditionalForm	the default format type for text
Frame	False	whether to put a frame around the plot
FrameLabel	None	frame labels
FrameStyle	{}	style specifications for the frame
FrameTicks	Automatic	frame ticks
FrameTicksStyle	{}	style specifications for frame ticks
GridLines	None	grid lines to draw
GridLinesStyle	{}	style specifications for grid lines
ImageMargins	0.	the margins to leave around the graphic
ImagePadding	All	what extra padding to allow for labels etc.
ImageSize	Automatic	the absolute size at which to render the graphic
LabelingFunction	Automatic	how to label points
LabelingSize	Automatic	maximum size of callouts and labels
LabelStyle	{}	style specifications for labels
Mesh	None	whether to draw mesh points on each curve
MeshStyle	Automatic	the style for mesh points
Method	Automatic	details of graphics methods to use
PerformanceGoal	$PerformanceGoal	aspects of performance to try to optimize
PlotLabel	None	an overall label for the plot
PlotLegends	None	legends for lines
PlotMarkers	None	markers to use to indicate each point
PlotRange	All	range of values to include
PlotRangeClipping	False	whether to clip at the plot range
PlotRangePadding	Automatic	how much to pad the range of values
PlotRegion	Automatic	the final display region to be filled
PlotStyle	Automatic	graphics directives to determine the style of each line
PlotTheme	$PlotTheme	overall theme for the plot
PreserveImageOptions	Automatic	whether to preserve image options when displaying new versions of the same graphic
Prolog	{}	primitives rendered before the main plot
RotateLabel	True	whether to rotate y labels on the frame
ScalingFunctions	None	how to scale individual coordinates
TargetUnits	Automatic	units to display in the plot
Ticks	Automatic	axes ticks
TicksStyle	{}	style specifications for axes ticks

Examples

open all close all

Basic Examples (3)

Plot a set of multidimensional points:

Wolfram Language code: ParallelAxisPlot[RandomChoice[Range[10], {5 , 5}]]

Plot multiple datasets:

Wolfram Language code: ParallelAxisPlot[{IconizedObject[«one»], IconizedObject[«two»], IconizedObject[«three»]}]

Use ColorFunction to style lines by the values on the first axis:

Wolfram Language code:

ParallelAxisPlot[{IconizedObject[«one»], IconizedObject[«two»], IconizedObject[«three»]}, ColorFunction -> (ColorData["Rainbow"][#]&)]

Scope (23)

General Data (6)

ParallelAxisPlot visualizes multidimensional data by placing each dimension on axes that are parallel to each other:

Wolfram Language code: ParallelAxisPlot[{{4, 5, 10, 7, 3}, {9, 8, 2, 2, 5}, {5, 3, 2, 7, 4}}]

By default, each axis has its own plot range:

Wolfram Language code: ParallelAxisPlot[{{4, 5, 10, 7, 3}, {9, 8, 2, 2, 5}, {5, 3, 2, 7, 4}}, PlotRange -> All]

PlotRangeAutomatic shows every axis in the same range:

Wolfram Language code: ParallelAxisPlot[{{4, 5, 10, 7, 3}, {9, 8, 2, 2, 5}, {5, 3, 2, 7, 4}}, PlotRange -> Automatic]

Plot multiple datasets:

Wolfram Language code:

ParallelAxisPlot[{RandomChoice[Range[0, 7], {5 , 5}], RandomChoice[Range[5, 10], {5 , 5}], RandomChoice[Range[10], {5 , 5}]}]

Plot data of unequal lengths:

Wolfram Language code: ParallelAxisPlot[{{6, 10, 5, 9, 7, 4}, {10, 5, 8, 6, 3}, {2, 5, 3}}]

Coordinates with nonreal values are left out:

Wolfram Language code: ParallelAxisPlot[{{8, 3, 5, 6, Missing[], 9}, {2, 6, a, 9, 12, 5}, {6, I, 3, 7, 5, 7}}]

Tabular Data (1)

Get tabular data:

Wolfram Language code: iris = ResourceData["Sample Tabular Data: Fisher Iris"]

Plot parallel axis to see relations per row on the table:

Wolfram Language code:

ParallelAxisPlot[iris -> {"SepalLength", "SepalWidth", "PetalLength", "PetalWidth"}, AxesLabel -> {"SepalLength", "SepalWidth", "PetalLength", "PetalWidth"}]

Special Data (2)

Use Quantity to include units with the data:

Wolfram Language code:

ParallelAxisPlot[{Quantity[Range[6], "Meters"], Quantity[Range[6], "Yards"], Quantity[Range[6], "Feet"]}, 
	PlotRange -> Automatic]

Plot the values in TimeSeries:

Wolfram Language code:

ParallelAxisPlot[{TimeSeries[{19, 16, 9, 3, 7, 2, 17}, {"May 24, 1982"}], 
	TimeSeries[{10, 19, 15, 3, 18, 17, 19}, {"May 24, 1982"}], 
	TimeSeries[{10, 11, 17, 18, 8, 7, 19}, {"May 24, 1982"}]}]

Keys in Association are automatically used as axes labels:

Wolfram Language code: ParallelAxisPlot[{<|"a" -> 1, "b" -> 2, "c" -> 3|>, <|"a" -> 3, "b" -> 1, "c" -> 2|>, <|"a" -> 5, "b" -> 1, "c" -> 4|>}]

Data Wrapper (4)

Use wrappers on datasets or collections of datasets:

Wolfram Language code:

{ParallelAxisPlot[{Style[{1, 3, 2, 4, 5}, Directive[Thick, Red]], {2, 4, 6, 2, 3}, {3, 1, 2, 1, 4}}], 
	ParallelAxisPlot[Style[{{1, 3, 2, 4, 5}, {2, 4, 6, 2, 3}, {3, 1, 2, 1, 4}}, Directive[Thick, Red]]]}

Wrappers can be nested:

Wolfram Language code:

ParallelAxisPlot[Style[{Style[{1, 3, 2, 4, 5}, Directive[Thick, Red]], {2, 4, 6, 2, 3}, {3, 1, 2, 1, 4}}, Directive[Dashed, Purple]]]

Use PopupWindow to provide additional drilldown information:

Wolfram Language code:

ParallelAxisPlot[{Style[PopupWindow[{1, 3, 2, 4, 5}, RadialAxisPlot[{1, 3, 2, 4, 5}]], Red], {2, 4, 6, 2, 3}, {3, 1, 2, 1, 4}}]

Button can be used to trigger any action:

Wolfram Language code:

ParallelAxisPlot[{Button[Style[{1, 3, 2, 4, 5}, Red], Print[RadialAxisPlot[{1, 3, 2, 4, 5}]]], {2, 4, 6, 2, 3}, {3, 1, 2, 1, 4}}]

Labeling and Legending (6)

Use LabelingFunction to add individual labels to each dataset:

Wolfram Language code: ParallelAxisPlot[RandomReal[1, {2, 4, 5}], LabelingFunction -> (Callout[RandomWord[]]&)]

Use the index of datasets provided to LabelingFunction to construct labels:

Wolfram Language code: labels = Table[RandomWord[], 2, 4]

Wolfram Language code: ParallelAxisPlot[RandomReal[1, {2, 4, 5}], LabelingFunction -> (Callout[Part[labels, Sequence@@#2]]&)]

Put labels before the lines:

Wolfram Language code: ParallelAxisPlot[RandomReal[1, {2, 4, 5}], LabelingFunction -> (Callout[Part[labels, Sequence@@#2], Before]&)]

Use Callout to add a label:

Wolfram Language code: ParallelAxisPlot[{Callout[{1, 3, 2, 4, 3}, "label"], {2, 4, 6, 2, 1}, {3, 1, 2, 1, 4}}]

Use PlotLegends to add a bar legend to represent the colors from ColorFunction:

Wolfram Language code: ParallelAxisPlot[RandomReal[10, {20, 5}], ColorFunction -> "Rainbow", PlotLegends -> Automatic]

Use legends to identify the color groups:

Wolfram Language code: ParallelAxisPlot[RandomReal[10, {3, 10, 5}], PlotLegends -> {"a", "b", "c"}]

Use Legended to add a legend:

Wolfram Language code: ParallelAxisPlot[{Legended[Style[{1, 3, 2, 4, 3}, Red], "label"], {2, 4, 6, 2, 1}, {3, 1, 2, 1, 4}}]

Presentation (4)

Multiple datasets are automatically colored to be distinct:

Wolfram Language code: ParallelAxisPlot[{IconizedObject[«one»], IconizedObject[«two»], IconizedObject[«three»]}]

Provide explicit styling to different curves:

Wolfram Language code:

ParallelAxisPlot[{IconizedObject[«one»], IconizedObject[«two»], IconizedObject[«three»]}, PlotStyle -> {RGBColor[0.8, 0.1, 0.1], Darker@Green, Hue[0.7]}]

Use a theme with high-contrast background and line style:

Wolfram Language code:

ParallelAxisPlot[{IconizedObject[«one»], IconizedObject[«two»], IconizedObject[«three»]}, PlotTheme -> "Marketing"]

Include a legend:

Wolfram Language code:

ParallelAxisPlot[{IconizedObject[«one»], IconizedObject[«two»], IconizedObject[«three»]}, PlotLegends -> Automatic]

Options (17)

AspectRatio (1)

By default,ParallelAxisPlot uses a fixed height to width ratio for the plot:

Wolfram Language code: data = RandomChoice[Range[10], {5, 5}];

Wolfram Language code: ParallelAxisPlot[data]

Make the height the same as the width with AspectRatio1:

Wolfram Language code: ParallelAxisPlot[data, AspectRatio -> 1]

AspectRatioAutomatic determines the ratio from the plot ranges:

Wolfram Language code: ParallelAxisPlot[data, AspectRatio -> Automatic]

AspectRatioFull adjusts the height and width to tightly fit inside other constructs:

Wolfram Language code: plot = ParallelAxisPlot[data, AspectRatio -> Full];

Wolfram Language code: {Framed[Pane[plot, {75, 100}]], Framed[Pane[plot, {150, 150}]], Framed[Pane[plot, {100, 75}]]}

Axes (4)

By default axes are drawn:

Wolfram Language code: ParallelAxisPlot[RandomInteger[10, {4, 5}]]

Use AxesFalse to turn off axes:

Wolfram Language code: ParallelAxisPlot[RandomInteger[10, {4, 5}], Axes -> False]

Show the axes using rules:

Wolfram Language code: ParallelAxisPlot[RandomInteger[10, {4, 5}], Axes -> {1 | 3 | 5 -> True, _ -> False}]

Using pattern test:

Wolfram Language code: ParallelAxisPlot[RandomInteger[10, {4, 5}], Axes -> {(_ ? OddQ | 4) -> True, _ -> False}]

AxesLabel (2)

Specify labels for axes:

Wolfram Language code: ParallelAxisPlot[RandomInteger[10, {4, 5}], AxesLabel -> Table[Row[{"Axis ", i}], {i, 5}]]

AxesLabel uses units as labels automatically:

Wolfram Language code:

ParallelAxisPlot[{Quantity[Range[6], "Meters"], Quantity[Range[6], "Yards"], Quantity[Range[6], "Feet"]}, 
	PlotRange -> Automatic]

AxesStyle (3)

Apply styles to the axes:

Wolfram Language code: ParallelAxisPlot[RandomInteger[10, {4, 5}], PlotRange -> {0, 10}, AxesStyle -> Red]

Specify different styles for axes in a list:

Wolfram Language code: ParallelAxisPlot[RandomInteger[10, {4, 5}], PlotRange -> {0, 10}, AxesStyle -> {Blue, Red, Green, Purple, Orange}]

Use rules:

Wolfram Language code: ParallelAxisPlot[RandomInteger[10, {4, 5}], PlotRange -> {0, 10}, AxesStyle -> (3 -> Red)]

ColorFunction (1)

Color the lines according to the values on the first axis:

Wolfram Language code: data = Table[Transpose[Table[Sort@RandomReal[NormalDistribution[u, 2], 10], {u, RandomReal[20, 6]}]], 2];

Wolfram Language code: ParallelAxisPlot[data, ColorFunction -> "Rainbow"]

Color lines by the fourth axis:

Wolfram Language code: ParallelAxisPlot[data, ColorFunction -> (ColorData["Rainbow", #4]&)]

ColorFunctionScaling (1)

Color the lines by the scaled values based on the range of color function:

Wolfram Language code: data = RandomReal[NormalDistribution[1 / 2, 1], {40, 5}];

Wolfram Language code: ColorData["Rainbow", "Range"]

Wolfram Language code: ParallelAxisPlot[data, ColorFunction -> "Rainbow"]

Color the lines by the unscaled values:

Wolfram Language code: ParallelAxisPlot[data, ColorFunctionScaling -> False, ColorFunction -> "Rainbow"]

PlotMarkers (3)

Use unique markers to identify different datasets:

Wolfram Language code: ParallelAxisPlot[RandomChoice[Range[10], {3, 3, 5}], PlotMarkers -> Automatic]

Specify marker size:

Wolfram Language code: ParallelAxisPlot[RandomChoice[Range[10], {3, 3, 5}], PlotMarkers -> {Automatic, 9}]

Specify custom markers:

Wolfram Language code: ParallelAxisPlot[RandomChoice[Range[10], {3, 3, 5}], PlotMarkers -> {{"♠", 14}, {"♣", 14}, {"♡", 14}}]

PlotRange (2)

Specify a plot range for all of the axes:

Wolfram Language code: ParallelAxisPlot[RandomInteger[10, {4, 5}], PlotRange -> {0, 10}]

Specify plot ranges for each axis:

Wolfram Language code: ParallelAxisPlot[RandomInteger[{0, 10}, {4, 5}], PlotRange -> {1 -> {0, 10}, _ -> {5, 10}}]

Applications (3)

Compare whether three points are close to each other. The blue point is separate from the yellow and green points in every dimension, while the yellow and green points differ only in the last two:

Wolfram Language code:

pdata = {RandomReal[{1, 1.2}, {1, 5}], RandomReal[{2, 2.2}, {1, 5}], Table[Join[RandomReal[{2, 2.2}, 3], RandomReal[{3, 3.2}, 2]], 1]};

Wolfram Language code: ParallelAxisPlot[pdata]

This can also be seen by plotting two coordinates at a time with ListPlot:

Wolfram Language code: {ListPlot[pdata[[All, All, {1, 2}]], Rule[...]], ListPlot[pdata[[All, All, {4, 5}]], Rule[...]]}

Use ParallelAxisPlot to visualize how some common operations work with built-in dynamic highlight on mouseover:

Wolfram Language code: n = 100;data = RandomReal[{0, 20}, n];

Wolfram Language code:

ParallelAxisPlot[Transpose[{data, Sort@data, -Sort@data, 2Sort@data, 2Sort@data + 15, Exp[Sort@data], 1 / Sort[data]}], ColorFunction -> (ColorData["Rainbow"][#2]&), AxesLabel -> {"random(x)", "x", "-x", "a*x", "a*x+b", "SuperscriptBox[e, x]", "1/x"}, ImageSize -> 400]

Use ParallelAxisPlot to visualize multidimensional statistic example data, Fisher Iris:

Wolfram Language code: irisdata = ExampleData[{"Statistics", "FisherIris"}];

Wolfram Language code: Take[irisdata, 3]

Group the data by the species and extract axes labels:

Wolfram Language code: data = GroupBy[irisdata, Last -> Most];

Wolfram Language code: axeslabels = ExampleData[{"Statistics", "FisherIris"}, "ColumnHeadings"]

Plot with ParallelAxisPlot:

Wolfram Language code: ParallelAxisPlot[data, PlotLegends -> Automatic, AxesLabel -> axeslabels, ImageSize -> Medium]

Find the median, 25% and 75% quantiles of the data and stylize them in bold and dashed lines:

Wolfram Language code:

newdata = Join[
	(*data*)
	#, 
	(*medium line*)
	{Style[Median@#, Directive[Opacity[1], Thickness[0.01]]]}, 
	(*quantile lines*)
	Style[#, Directive[Opacity[1], Dashed, Thickness[0.005]]]& /@ Transpose@Quantile[#, {0.25, 0.75}]
	]& /@ data;

Wolfram Language code:

ParallelAxisPlot[newdata, PlotLegends -> LineLegend[97, Keys[newdata]], PlotStyle -> Opacity[0.2], AxesLabel -> axeslabels, ImageSize -> Medium]

Properties & Relations (3)

ParallelAxisPlot plots multidimensional points on multiple parallel axes:

Wolfram Language code: ParallelAxisPlot[{{1, 1, 1, 1, 1}, {1, 2, 3, 4, 5}, {5, 5, 5, 5, 5}}]

ListPlot and ListLinePlot plot multiple points on two perpendicular axes:

Wolfram Language code:

{ListPlot[{{1, 1, 1, 1, 1}, {1, 2, 3, 4, 5}, {5, 5, 5, 5, 5}}], ListLinePlot[{{1, 1, 1, 1, 1}, {1, 2, 3, 4, 5}, {5, 5, 5, 5, 5}}]}

RadialAxisPlot plots multidimensional points on multiple axes with a shared point at the origin:

Wolfram Language code:

{ParallelAxisPlot[{{1, 1, 1, 1, 1}, {1, 2, 3, 4, 5}, {5, 5, 5, 5, 5}}], RadialAxisPlot[{{1, 1, 1, 1, 1}, {1, 2, 3, 4, 5}, {5, 5, 5, 5, 5}}]}

ParallelAxisPlot is similar to NumberLinePlot for one-dimensional points:

Wolfram Language code: {ParallelAxisPlot[{{1}, {2}, {3}}, PlotStyle -> Red], NumberLinePlot[{{1}, {2}, {3}}, PlotStyle -> Red]}

Top

	y_i	a real-valued number
	Quantity[y_i,unit]	a quantity with a unit

	w[{y₁,…,y_n}]	wrap a point
	w[{data₁,…}]	wrap a set of points data_i
	w₁[w₂[…]]	use nested wrappers

ParallelAxisPlot

Details and Options

List of all options

Examples

Basic Examples (3)

Scope (23)

General Data (6)

Tabular Data (1)

Special Data (2)

Data Wrapper (4)

Labeling and Legending (6)

Presentation (4)

Options (17)

AspectRatio (1)

Axes (4)

AxesLabel (2)

AxesStyle (3)

ColorFunction (1)

ColorFunctionScaling (1)

PlotMarkers (3)

PlotRange (2)

Applications (3)

Properties & Relations (3)

See Also

Related Guides

History

Text

CMS

APA

BibTeX

BibLaTeX