Sitelet https://reference.wolfram.com/language/ref/SystemsModelLinearity.html

WOLFRAM

Wolfram Language & System Documentation Center

SystemsModelLinearity[sys]

gives the linearity of the systems model sys.

SystemsModelLinearity[{sys,{in1,…},{out1,…},{s1,…}}]

only considers the subsystem associated with inputs ini, outputs outj, and states sk.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Applications  
Properties & Relations  
See Also
Related Guides
History
Cite this Page

SystemsModelLinearity

SystemsModelLinearity[sys]

gives the linearity of the systems model sys.

SystemsModelLinearity[{sys,{in1,…},{out1,…},{s1,…}}]

only considers the subsystem associated with inputs ini, outputs outj, and states sk.

Details

  • SystemsModelLinearity is typically used to determine whether a NonlinearStateSpaceModel or AffineStateSpaceModel satisfies additional linearity conditions, which would allow it to be exactly converted to a more specialized form and thus making a wider range of design and analysis techniques applicable.
  • Possible systems models sys include TransferFunctionModel, StateSpaceModel, AffineStateSpaceModel, and NonlinearStateSpaceModel.
  • A state space model with state , input , state equations and output equations can be classified based on what variables in and occur linearly.
  • Possible values and the structural form required for both and are given below:
  • "Linear"linear in states and inputs,
    "Bilinear"linear in states and inputs separately,
    "StateLinear"linear only in states,
    "InputLinear"linear only in inputs,
    "Nonlinear"not linear in either states or inputs

Examples

open all close all

Basic Examples  (2)

A linear mass-spring-damper (MSD) model:

Wolfram Language code: NonlinearStateSpaceModel[m x''[t] + c x'[t] + k x[t] == u[t], x[t], u[t], x[t], t];
Wolfram Language code: SystemsModelLinearity[%]

A MSD model with the spring having cubic nonlinearity:

Wolfram Language code: NonlinearStateSpaceModel[m x''[t] + c x'[t] + Subscript[k, 1] x[t] + Subscript[k, 2]x[t]^3 == u[t], x[t], u[t], x[t], t];
Wolfram Language code: SystemsModelLinearity[%]

Scope  (7)

A linear model:

Wolfram Language code: SystemsModelLinearity[StateSpaceModel[{{{a}}, {{b}}, {{c}}, {{d}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]

A NonlinearStateSpaceModel that is linear:

Wolfram Language code: SystemsModelLinearity[NonlinearStateSpaceModel[{{b*u + a*x}, {d*u + c*x}}, {x}, {u}, {Automatic}, Automatic, SamplingPeriod -> None]]

A bilinear model:

Wolfram Language code: SystemsModelLinearity[NonlinearStateSpaceModel[ {{a*x + u*Subscript[b, 0] + u*x*Subscript[b, 1]}, {d*u + c*x}}, {x}, {u}, {Automatic}, Automatic, SamplingPeriod -> None]]

An input-linear model:

Wolfram Language code: SystemsModelLinearity[NonlinearStateSpaceModel[{{x*Subscript[a, 1] + x^2*Subscript[a, 2] + u*Subscript[b, 0] + u*x*Subscript[b, 1]}, {d*u + c*x}}, {x}, {u}, {Automatic}, Automatic, SamplingPeriod -> None]]

A model that is not linear:

Wolfram Language code: SystemsModelLinearity[NonlinearStateSpaceModel[{{x*Subscript[a, 1] + x^2*Subscript[a, 2] + u*Subscript[b, 0] + u*x*Subscript[b, 1] + u^2*Subscript[b, 2]}, {d*u + c*x}}, {x}, {u}, {Automatic}, Automatic, SamplingPeriod -> None]]

Frequency domain models are linear models:

Wolfram Language code: SystemsModelLinearity[TransferFunctionModel[{{{b + s}}, a + s}, s]]

A model with linear state equations:

Wolfram Language code: SystemsModelLinearity[{NonlinearStateSpaceModel[{{b*u + a*x}, {u + x + x^2}}, {x}, {u}, {Automatic}, Automatic, SamplingPeriod -> None], All, None, All}]

Applications  (2)

Verify the linearization obtained using StateTransformationLinearize:

Wolfram Language code: ℒ = StateTransformationLinearize[AffineStateSpaceModel[{{4*Subscript[x, 1], 7*Subscript[x, 1]^2 + Subscript[x, 2]}, {{1}, {-1 + 2*Subscript[x, 1]}}, {Subscript[x, 1] - Subscript[x, 2]}, {{0}}}, {Subscript[x, 1], Subscript[x, 2]}, {{Subscript[, 1], 0}}, {Automatic}, Automatic, SamplingPeriod -> None]]
Wolfram Language code: sys = ℒ["TransformedSystem"]

Check if it is input-output linear:

Wolfram Language code: SystemsModelLinearity[sys] === "Linear"

Check if it is state-output linear:

Wolfram Language code: SystemsModelLinearity[{sys, None, All}] === "Linear"

Check if it is input-state linear:

Wolfram Language code: SystemsModelLinearity[{sys, All, None}] === "Linear"

Compute the linearization after systems connections:

Wolfram Language code: {sys1, sys2} = {TransferFunctionModel[{{{1, 2}}, {{4 + s, 3 + s}}}, s], NonlinearStateSpaceModel[{{Subscript[x, 2], u - 4*Subscript[x, 1] - Subscript[x, 2]^2}, {Subscript[x, 1]}}, {Subscript[x, 1], Subscript[x, 2]}, {u}, {Automatic}, Automatic, SamplingPeriod -> None]};

Connect the two systems in a series:

Wolfram Language code: sys = SystemsModelSeriesConnect[sys1, sys2]

The linearity of the original and connected systems:

Wolfram Language code: SystemsModelLinearity /@ {sys1, sys2, sys}

Properties & Relations  (4)

A linear system obeys the principles of superposition and homogeneity:

Wolfram Language code: lsys = StateSpaceModel[{{{-1}}, {{1}}, {{1}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None];
Wolfram Language code: SystemsModelLinearity[lsys]

Its response to the input signal :

Wolfram Language code: r1 = OutputResponse[lsys, Sin[t], {t, 0, 15}]; Plot[r1, {t, 0, 15}]

Its response to TemplateBox[{t}, UnitStepSeq]:

Wolfram Language code: r2 = OutputResponse[lsys, UnitStep[t], {t, 0, 15}]; Plot[r2, {t, 0, 15}, PlotRange -> All]

The response to 3 sin(t)+5 TemplateBox[{t}, UnitStepSeq] is the same as :

Wolfram Language code: OutputResponse[lsys, 3 Sin[t] + 5 UnitStep[t], {t, 0, 15}];
Wolfram Language code: Plot[{%, 3r1 + 5r2}, {t, 0, 15}]

Typically StateSpaceModel is used to model linear state-space models:

Wolfram Language code: lsys = StateSpaceModel[{{{a}}, {{b}}, {{c}}, {{d}}}, SamplingPeriod -> None, SystemsModelLabels -> None];
Wolfram Language code: SystemsModelLinearity[lsys]

The model can be exactly converted to any other systems model:

Wolfram Language code: AffineStateSpaceModel[lsys]
Wolfram Language code: NonlinearStateSpaceModel[lsys]

Typically AffineStateSpaceModel is used for models that are bilinear or input-linear:

Wolfram Language code: asys = AffineStateSpaceModel[{{x + a[x]}, {{x + b[x]}}, {x + c[x]}, {{0}}}, {x}, Automatic, {Automatic}, Automatic, SamplingPeriod -> None];
Wolfram Language code: SystemsModelLinearity[asys]

It can be exactly converted to NonlinearStateSpaceModel:

Wolfram Language code: NonlinearStateSpaceModel[asys]

Conversion to other systems models is approximate:

Wolfram Language code: StateSpaceModel[asys]

Use NonlinearStateSpaceModel for models that are not linear:

Wolfram Language code: nsys = NonlinearStateSpaceModel[ {{u + x + f[x, u]}, {u + x + g[x, u]}}, {x}, {u}, {Automatic}, Automatic, SamplingPeriod -> None];
Wolfram Language code: SystemsModelLinearity[nsys]

Conversion to any other systems model is approximate:

Wolfram Language code: AffineStateSpaceModel[nsys]
Wolfram Language code: StateSpaceModel[nsys]
Wolfram Research (2014), SystemsModelLinearity, Wolfram Language function, https://reference.wolfram.com/language/ref/SystemsModelLinearity.html.

Text

Wolfram Research (2014), SystemsModelLinearity, Wolfram Language function, https://reference.wolfram.com/language/ref/SystemsModelLinearity.html.

CMS

Wolfram Language. 2014. "SystemsModelLinearity." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/SystemsModelLinearity.html.

APA

Wolfram Language. (2014). SystemsModelLinearity. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/SystemsModelLinearity.html

BibTeX

@misc{reference.wolfram_2026_systemsmodellinearity, author="Wolfram Research", title="{SystemsModelLinearity}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/SystemsModelLinearity.html}", note=[Accessed: 05-October-2026]}

BibLaTeX

@online{reference.wolfram_2026_systemsmodellinearity, organization={Wolfram Research}, title={SystemsModelLinearity}, year={2014}, url={https://reference.wolfram.com/language/ref/SystemsModelLinearity.html}, note=[Accessed: 05-October-2026]}