SystemsModelExtract
SystemsModelExtract[sys,{in1,…}]
extracts the subsystem of the systems model sys associated with inputs at position ini.
SystemsModelExtract[sys,{in1,…},{out1,…}]
extracts the subsystem associated with inputs and outputs at positions ini and outi, respectively.
SystemsModelExtract[sys,{in1,…},{out1,…},{s1,…}]
extracts the subsystem of the state-space model sys associated with inputs, outputs, and states at ini, outi, and si, respectively.
Details
- The systems model sys can be a TransferFunctionModel, StateSpaceModel, AffineStateSpaceModel, or NonlinearStateSpaceModel.
- The specifications of the inputs, outputs, and states can also be All or None.
Examples
open all close allBasic Examples (2)
Extract the subsystem associated with the first input and third output:
SystemsModelExtract[TransferFunctionModel[{{{1, 0}, {2, s}, {2, s^2}},
{{0.5 + s, 1}, {1, 3 + 0.1*s + s^2},
{1 + 2*s + s^2, 1 + 3*s^2 + s^3}}},
s], {1}, {3}]Extract the subsystem associated with the first two states:
SystemsModelExtract[StateSpaceModel[{{{Subscript[a, 1], 0, 0}, {0, Subscript[a, 2], 0},
{0, 0, Subscript[a, 3]}}, {{Subscript[b, 1], 0, 0},
{0, Subscript[b, 2], 0}, {0, 0, Subscript[b, 3]}},
{{Subscript[c, 1], 0, 0}, {0, Subscript[c, 2], 0},
{0, 0, Subscript[c, 3]}}, {{Subscript[d, 1], 0, 0},
{0, Subscript[d, 2], 0}, {0, 0, Subscript[d, 3]}}},
SamplingPeriod -> None, SystemsModelLabels -> None], All, All, {1, 2}]Scope (8)
Extract the subsystem associated with the first input of a three-input system:
SystemsModelExtract[TransferFunctionModel[{{{s, 4*s, 3}, {1, 1, 1}},
{{3 + s, 2 + s, 2 + s},
{3 + s, s, s}}}, s,
SystemsModelLabels -> {{Subscript[u, 1], Subscript[u, 2],
Subscript[u, 3]}, {Subscript[y, 1], Subscript[y, 2]}}], {1}]The subsystem associated with the second output:
SystemsModelExtract[TransferFunctionModel[{{{s, 4*s, 3}, {1, 1, 1}},
{{3 + s, 2 + s, 2 + s},
{3 + s, s, s}}}, s,
SystemsModelLabels -> {{Subscript[u, 1], Subscript[u, 2],
Subscript[u, 3]}, {Subscript[y, 1], Subscript[y, 2]}}], All, {2}]Extract the subsystem corresponding to the first and second inputs, and the third and fourth outputs:
SystemsModelExtract[StateSpaceModel[{{{-1, 0, 0, 0}, {0, -3, 0, 0}, {0, 0, -4, 0}, {0, 0, 0, -8}},
{{1, 0, 0}, {1, -1, 0}, {0, 0, 1}, {1, 1, 0}}, {{1, 0, 0, 0}, {0, 1, 0, 0}, {0, 0, 1, 0},
{0, 0, 0, 1}}, {{0, 0, 0}, {0, 0, 0}, {0, 0, 0}, {0, 0, 0}}}, SamplingPeriod -> None,
SystemsModelLabels -> None], {1, 2}, {3, 4}]Extract the subsystem associated with the second and third states of a state-space model:
SystemsModelExtract[StateSpaceModel[{{{-1, 0, 0, 0}, {0, -3, 0, 0}, {0, 0, -4, 0}, {0, 0, 0, -8}},
{{1, 0, 0}, {1, -1, 0}, {0, 0, 1}, {1, 1, 0}}, {{1, 0, 0, 0}, {0, 1, 0, 0}, {0, 0, 1, 0},
{0, 0, 0, 1}}, {{0, 0, 0}, {0, 0, 0}, {0, 0, 0}, {0, 0, 0}}}, SamplingPeriod -> None,
SystemsModelLabels -> None], All, All, {2, 3}]The subsystem associated with the third and fourth states:
SystemsModelExtract[StateSpaceModel[{{{1, 2, 0, 0}, {0, 2, 0, 0}, {2, 1, 0, 1}, {0, 2, 1, 1}}, {{0}, {0}, {1}, {0}},
{{1, 0, 0, 0}, {0, 1, 0, 0}, {0, 0, 1, 0}, {0, 0, 0, 1}}, {{0}, {0}, {0}, {0}}},
SamplingPeriod -> None, SystemsModelLabels -> None], All, All, {3, 4}]Extract the last two states of a descriptor StateSpaceModel:
SystemsModelExtract[StateSpaceModel[{{{Subscript[a, 11], Subscript[a, 12],
Subscript[a, 13]}, {Subscript[a, 21], Subscript[a, 22],
Subscript[a, 23]}, {Subscript[a, 31], Subscript[a, 32],
Subscript[a, 33]}}, {{Subscript[b, 1]},
{Subscript[b, 2]}, {Subscript[b, 3]}},
{{Subscript[c, 1], Subscript[c, 2], Subscript[c, 3]}},
{{d}}, {{Subscript[e, 11], Subscript[e, 12],
Subscript[e, 13]}, {Subscript[e, 21], Subscript[e, 22],
Subscript[e, 23]}, {Subscript[e, 31], Subscript[e, 32],
Subscript[e, 33]}}}, SamplingPeriod -> None, SystemsModelLabels -> None], All, All, {-2, -1}]Extract the first and second states of an AffineStateSpaceModel:
SystemsModelExtract[AffineStateSpaceModel[{{Subscript[a, 1][Subscript[x, 1],
Subscript[x, 2], Subscript[x, 3]],
Subscript[a, 2][Subscript[x, 1], Subscript[x, 2],
Subscript[x, 3]], Subscript[a, 3][Subscript[x, 1],
Subscript[x, 2], Subscript[x, 3]]},
{{Subscript[b, 1][Subscript[x, 1], Subscript[x, 2],
Subscript[x, 3]]}, {Subscript[b, 2][Subscript[x, 1],
Subscript[x, 2], Subscript[x, 3]]},
{Subscript[b, 3][Subscript[x, 1], Subscript[x, 2],
Subscript[x, 3]]}}, {c[Subscript[x, 1],
Subscript[x, 2], Subscript[x, 3]]},
{{d[Subscript[x, 1], Subscript[x, 2],
Subscript[x, 3]]}}},
{{Subscript[x, 1], Subscript[x, 10]},
{Subscript[x, 2], Subscript[x, 20]},
{Subscript[x, 3], Subscript[x, 30]}}, Automatic, {Automatic},
Automatic, SamplingPeriod -> None], All, All, {1, 2}]By default the operating points are assumed to be zero:
SystemsModelExtract[AffineStateSpaceModel[{{Subscript[a, 1][Subscript[x, 1],
Subscript[x, 2], Subscript[x, 3]],
Subscript[a, 2][Subscript[x, 1], Subscript[x, 2],
Subscript[x, 3]], Subscript[a, 3][Subscript[x, 1],
Subscript[x, 2], Subscript[x, 3]]},
{{Subscript[b, 1][Subscript[x, 1], Subscript[x, 2],
Subscript[x, 3]]}, {Subscript[b, 2][Subscript[x, 1],
Subscript[x, 2], Subscript[x, 3]]},
{Subscript[b, 3][Subscript[x, 1], Subscript[x, 2],
Subscript[x, 3]]}}, {c[Subscript[x, 1],
Subscript[x, 2], Subscript[x, 3]]},
{{d[Subscript[x, 1], Subscript[x, 2],
Subscript[x, 3]]}}}, {Subscript[x, 1], Subscript[x, 2],
Subscript[x, 3]}, Automatic, {Automatic}, Automatic, SamplingPeriod -> None], All, All, {1, 2}]Extract the first input of a NonlinearStateSpaceModel:
SystemsModelExtract[NonlinearStateSpaceModel[{{f[x, Subscript[u, 1],
Subscript[u, 2]]}, {g[x, Subscript[u, 1],
Subscript[u, 2]]}}, {x}, {Subscript[u, 1],
Subscript[u, 2]}, {Automatic}, Automatic, SamplingPeriod -> None], 1]A system with a nonzero operating point:
SystemsModelExtract[NonlinearStateSpaceModel[{{f[x, Subscript[u, 1],
Subscript[u, 2]]}, {g[x, Subscript[u, 1],
Subscript[u, 2]]}}, {{x, Subscript[x, 0]}},
{{Subscript[u, 1], Subscript[u, 10]},
{Subscript[u, 2], Subscript[u, 20]}}, {Automatic}, Automatic,
SamplingPeriod -> None], 1]Applications (4)
Rearrange the inputs of a system:
SystemsModelExtract[StateSpaceModel[{{{Subscript[a, 1], 0, 0}, {0, Subscript[a, 2], 0},
{0, 0, Subscript[a, 3]}}, {{Subscript[b, 1], 0, 0},
{0, Subscript[b, 2], 0}, {0, 0, Subscript[b, 3]}},
{{Subscript[c, 1], 0, 0}, {0, Subscript[c, 2], 0},
{0, 0, Subscript[c, 3]}}, {{Subscript[d, 1], 0, 0},
{0, Subscript[d, 2], 0}, {0, 0, Subscript[d, 3]}}},
SamplingPeriod -> None, SystemsModelLabels -> None], {1, 3, 2}]SystemsModelExtract[StateSpaceModel[{{{Subscript[a, 1], 0, 0}, {0, Subscript[a, 2], 0},
{0, 0, Subscript[a, 3]}}, {{Subscript[b, 1], 0, 0},
{0, Subscript[b, 2], 0}, {0, 0, Subscript[b, 3]}},
{{Subscript[c, 1], 0, 0}, {0, Subscript[c, 2], 0},
{0, 0, Subscript[c, 3]}}, {{Subscript[d, 1], 0, 0},
{0, Subscript[d, 2], 0}, {0, 0, Subscript[d, 3]}}},
SamplingPeriod -> None, SystemsModelLabels -> None], All, {2, 3, 1}]SystemsModelExtract[StateSpaceModel[{{{Subscript[a, 1], 0, 0}, {0, Subscript[a, 2], 0},
{0, 0, Subscript[a, 3]}}, {{Subscript[b, 1], 0, 0},
{0, Subscript[b, 2], 0}, {0, 0, Subscript[b, 3]}},
{{Subscript[c, 1], 0, 0}, {0, Subscript[c, 2], 0},
{0, 0, Subscript[c, 3]}}, {{Subscript[d, 1], 0, 0},
{0, Subscript[d, 2], 0}, {0, 0, Subscript[d, 3]}}},
SamplingPeriod -> None, SystemsModelLabels -> None], All, All, {2, 1, 3}]Use SystemsModelExtract to obtain the responses of individual subsystems of a MIMO system:
tfm = TransferFunctionModel[{{{1, s}, {1, s}, {1, 1}},
{{1 + s, 2 + s}, {2 + s,
3 + 0.1*s + s^2}, {1 + 2*s + s^2,
9 + s^2}}}, s];subSystems = Outer[SystemsModelExtract[tfm, #1, #2]&, Sequence@@(Range /@ SystemsModelDimensions[tfm])]//Transpose;The output response to a unit step input for each subsystem:
Map[Plot[OutputResponse[#, UnitStep[t], {t, 10}]//Evaluate, {t, 0, 10}, PlotRange -> All]&, subSystems, {2}]//TableFormThe output response of all the subsystems:
Plot[OutputResponse[tfm, {UnitStep[t], UnitStep[t]}, {t, 10}]//Evaluate, {t, 0, 10}, PlotRange -> All]The Nyquist plots for each subsystem:
Map[NyquistPlot, subSystems, {2}]//TableFormVisualize the response of specific outputs to specific inputs for a MIMO system:
tfm = TransferFunctionModel[{{{1 + s, -1 - s},
{-1 + s, 1 + s}},
{{2 + s, (-1 + s)*(2 + s)},
{2 + s, 2 + s}}}, s];The response of the outputs to a unit step applied only to the first input:
Plot[OutputResponse[SystemsModelExtract[tfm, 1], UnitStep[t], {t, 10}]//Evaluate, {t, 0, 10}]The response of the second output to excitations in both inputs:
Plot[OutputResponse[SystemsModelExtract[tfm, All, 2], {Sin[t], Sin[3t]}, {t, 20}]//Evaluate, {t, 0, 20}]In some cases it is possible to extract the controllable and observable subsystems by visual observation:
ssm = StateSpaceModel[{{{1, 0, 0, 0}, {0, 1, 1, 0}, {0, 1, 0, 0}, {0, 0, 0, 1}},
{{1, 0}, {0, 1}, {0, 1}, {0, 0}}, {{0, 2, 1, 0}}, {{0, 0}}}, SamplingPeriod -> None,
SystemsModelLabels -> None];{ControllableModelQ[ssm], ObservableModelQ[ssm]}Only the first three modes are controllable:
SystemsModelExtract[ssm, All, All, {1, 2, 3}]ControllableDecomposition gives the same result:
ControllableDecomposition[ssm]//LastOnly modes 2 and 3 are observable:
SystemsModelExtract[ssm, All, All, {2, 3}]ObservableDecomposition gives the same result:
ObservableDecomposition[ssm]//LastProperties & Relations (1)
The specifications in SystemsModelExtract and SystemsModelDelete are complementary:
ssm = StateSpaceModel[{Array[Subscript[a, ##]&, {5, 5}], Array[Subscript[b, ##]&, {5, 3}], Array[Subscript[c, ##]&, {4, 5}]}]SystemsModelExtract[ssm, {1, 2}, {3, 4}, {2, 5}]SystemsModelDelete[ssm, Complement[Range[3], {1, 2}], Complement[Range[4], {3, 4}], Complement[Range[5], {2, 5}]]Text
Wolfram Research (2010), SystemsModelExtract, Wolfram Language function, https://reference.wolfram.com/language/ref/SystemsModelExtract.html (updated 2014).
CMS
Wolfram Language. 2010. "SystemsModelExtract." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2014. https://reference.wolfram.com/language/ref/SystemsModelExtract.html.
APA
Wolfram Language. (2010). SystemsModelExtract. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/SystemsModelExtract.html