Sitelet https://reference.wolfram.com/language/ref/KernelFunction.html

WOLFRAM

Wolfram Language & System Documentation Center

KernelFunction[f]

represents a function to be evaluated in the Wolfram Language kernel, even when called from compiled code.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Properties & Relations  
Possible Issues  
Neat Examples  
See Also
Tech Notes
Related Guides
History
Cite this Page

KernelFunction

KernelFunction[f]

represents a function to be evaluated in the Wolfram Language kernel, even when called from compiled code.

Details

  • The function f in KernelFunction[f] can be a built-in Wolfram Language function, a Function object or a function with definitions given by the user.
  • Typically, KernelFunction is wrapped in TypeHint to specify the type of the function.
  • FunctionDeclaration[fcomp,Typed[KernelFunction[feval],argTysresTy]] is shorthand for declaring a function that evaluates feval using the Wolfram Engine within the compiled function fcomp.

Examples

open all close all

Basic Examples  (3)

Use the Wolfram Engine evaluator to compute the AiryAi function from compiled code:

Wolfram Language code: cf = FunctionCompile[Function[Typed[arg, "Real64"], Typed[KernelFunction[AiryAi], {"Real64"} -> "Real64"][arg]]]

Execute the compiled function:

Wolfram Language code: {cf[1.1], AiryAi[1.1]}

The result compares with the direct call:

Wolfram Language code: AiryAi[1.1]

Call a pure function that executes using the evaluator:

Wolfram Language code: cf = FunctionCompile[Function[Typed[arg, "Real64"], TypeHint[KernelFunction[# + 10&], {"Real64"} -> "Real64"][arg]]]
Wolfram Language code: cf[ 10.2]

Define a function in the Wolfram Engine:

Wolfram Language code: f[x_] := x ^ 2

Call the function from compiled code:

Wolfram Language code: cf = FunctionCompile[Function[Typed[arg, "MachineInteger"], TypeHint[KernelFunction[f], {"MachineInteger"} -> "MachineInteger"][arg]]]
Wolfram Language code: cf[10]

Scope  (4)

Use the result of KernelFunction as an internal function:

Wolfram Language code: cf = FunctionCompile[Function[{Typed[cond, "Boolean"], Typed[arg, "Real64"]}, Module[{f1 = TypeHint[KernelFunction[# + 10&], {"Real64"} -> "Real64"], f2 = TypeHint[KernelFunction[# + 10&], {"Real64"} -> "Real64"]}, If[cond, f1[arg], f2[arg]]]]]
Wolfram Language code: cf[ True, 10.2]

A KernelFunction can return a function:

Wolfram Language code: cf = FunctionCompile[Function[Typed[arg, "Real64"], Module[{f1 = TypeHint[KernelFunction[Function[{}, # + 10&]], {} -> {"Real64"} -> "Real64"][]}, f1[arg]]]]
Wolfram Language code: cf[ 10.2]

Returning a function from KernelFunction allows operations such as Fit to be integrated into the compiler:

Wolfram Language code: func = Function[{Typed[data, TypeSpecifier["PackedArray"]["Real64", 2]], Typed[arg, "Real64"]}, Module[{f1 = TypeHint[ KernelFunction[ Function@@{x, Fit[#, {1, x}, x]}&], {TypeSpecifier["PackedArray"]["Real64", 2]} -> {"Real64"} -> "Real64"][data]}, f1[ arg]]]; cf = FunctionCompile[func]
Wolfram Language code: cf[ {{0., 1.}, {1., 0.}, {3., 2.}, {5., 4.}}, 1.2]

The function returned from KernelFunction can itself be dynamically compiled:

Wolfram Language code: func = Function[{Typed[data, TypeSpecifier["PackedArray"]["Real64", 2]], Typed[arg, "Real64"]}, Module[{f1 = TypeHint[ KernelFunction[ FunctionCompile[Function@@{Typed[x, "Real64"], Fit[#, {1, x}, x]}]&], {TypeSpecifier["PackedArray"]["Real64", 2]} -> {"Real64"} -> "Real64"][data]}, f1[ arg]]]; cf = FunctionCompile[func]
Wolfram Language code: cf[{{0., 1.}, {1., 0.}, {3., 2.}, {5., 4.}}, 1.2]

Use KernelFunction to integrate file operations:

Wolfram Language code: path = CreateFile[]; Put[RandomReal[100, 100], path];
Wolfram Language code: cf = FunctionCompile[Function[{}, Module[{data}, data = TypeHint[KernelFunction[Get[path]&], {} -> "PackedArray"["Real64", 1]][]; Fold[Plus, data] ]]]
Wolfram Language code: cf[]

Properties & Relations  (1)

Use KernelFunction alongside FunctionDeclaration to declare functions that require the evaluator:

Wolfram Language code: cf = FunctionCompile[ FunctionDeclaration[ myAiryAi, Typed[KernelFunction[AiryAi], {"Real64"} -> "Real64"] ], Function[Typed[arg, "Real64"], myAiryAi[arg]] ]
Wolfram Language code: cf[1.1]

Possible Issues  (1)

Not all Wolfram Language symbols are currently supported by the compiler:

Wolfram Language code: FunctionCompile[Function[Typed[str, "String"], StringFormat[str]]]

If necessary, functions can be declared using KernelFunction to call such functions from compiled code:

Wolfram Language code: cf = FunctionCompile[ FunctionDeclaration[StringFormat, Typed[KernelFunction[StringFormat], {"String"} -> "String"]], Function[Typed[str, "String"], StringFormat[str]] ]; cf /@ {"1,2 3,4 5,6 ", "1 2 3 4 5 6 "}

Neat Examples  (1)

Integrate NDSolve into compiled code:

Wolfram Language code: func = Function[{Typed[arg1, "Real64"], Typed[arg2, "Real64"]}, Module[{f = Typed[ KernelFunction[Function[{init}, First[y /. NDSolve[{y'[x] == y[x] Cos[x + y[x]], y[0] == init}, y, {x, 0, 30}]]]], {"Real64"} -> {"Real64"} -> "Real64"][arg1]}, f[arg2]]]; cf = FunctionCompile[func]
Wolfram Language code: cf[0.2, 0.0]
Wolfram Research (2019), KernelFunction, Wolfram Language function, https://reference.wolfram.com/language/ref/KernelFunction.html.

Text

Wolfram Research (2019), KernelFunction, Wolfram Language function, https://reference.wolfram.com/language/ref/KernelFunction.html.

CMS

Wolfram Language. 2019. "KernelFunction." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/KernelFunction.html.

APA

Wolfram Language. (2019). KernelFunction. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/KernelFunction.html

BibTeX

@misc{reference.wolfram_2026_kernelfunction, author="Wolfram Research", title="{KernelFunction}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/KernelFunction.html}", note=[Accessed: 04-October-2026]}

BibLaTeX

@online{reference.wolfram_2026_kernelfunction, organization={Wolfram Research}, title={KernelFunction}, year={2019}, url={https://reference.wolfram.com/language/ref/KernelFunction.html}, note=[Accessed: 04-October-2026]}