FunctionCompileExportLibrary
FunctionCompileExportLibrary[file,fspec]
exports a compiled version of function specification fspec as a shared library suitable for external use.
FunctionCompileExportLibrary[file,defs,fspec]
uses the auxiliary definitions defs for compilation.
Details and Options
- FunctionCompileExportLibrary generates a library suitable for use on the type of computer on which it is run.
- Functions can be given as a Function pure function, a list of pure functions or an association of pure functions.
- Auxiliary definitions can be given with FunctionDeclaration or by giving a CompilerEnvironment option.
- The following library types are generated on different types of systems:
-
Macintosh .dylib Windows .dll Linux .so - The following option can be given:
-
CompilerEnvironment Automatic an environment of definitions for compilation ProgressReporting Automatic how to report progress during the compilation - By default, FunctionCompileExportLibrary creates a library in the current directory given by Directory[].
- FunctionCompileExportLibrary has the option CompilerOptions, which allows detailed options to be passed to different parts of the compilation pipeline.
- The library generated by FunctionCompileExportLibrary is suitable for linking into external programs. It can also be loaded into the Wolfram System using LibraryFunctionLoad.
Examples
open all close allBasic Examples (4)
Export a compiled version of a function into a library:
lib = FunctionCompileExportLibrary["function.dylib", Function[Typed[arg, "MachineInteger"], arg + 1]]Load the library and create a CompiledCodeFunction:
fun = LibraryFunctionLoad[lib]Execute the function in the CompiledCodeFunction:
fun[10]The file can be an absolute path:
FunctionCompileExportLibrary[FileNameJoin[{$HomeDirectory, "tmp", "function.dylib"}], Function[Typed[arg, "MachineInteger"], arg + 1]]Several functions can be compiled with FunctionCompileExportLibrary:
lib = FunctionCompileExportLibrary["functionlist.dylib", {Function[Typed[arg, "Integer64"], arg + 1], Function[Typed[arg, "Integer64"], arg - 1]}];Loading the library creates a list of compiled code functions:
funs = LibraryFunctionLoad[lib]Execute the code that was loaded:
funs[[1]][10] + funs[[2]][20]Several functions can be compiled with FunctionCompileExportLibrary:
lib = FunctionCompileExportLibrary["functionassociation.dylib", <|"f1" -> Function[Typed[arg, "Integer64"], arg + 1], "f2" -> Function[Typed[arg, "Integer64"], arg - 1]|>];Loading the library creates a list of compiled code functions:
funs = LibraryFunctionLoad[lib]Execute the code that was loaded:
funs["f1"][10] + funs["f2"][20]Auxiliary definitions can be given with FunctionDeclaration:
lib = FunctionCompileExportLibrary["functiondef.dylib", FunctionDeclaration[AddTwo, Typed[{"Integer64"} -> "Integer64"]@Function[arg, 2 + arg]], Function[Typed[arg, "Integer64"], AddTwo[AddTwo[arg]]]];Load and execute code in the library:
fun = LibraryFunctionLoad[lib];
fun[10]Options (2)
CompilerEnvironment (1)
Create a compiler environment and add a function definition:
env = CreateCompilerEnvironment[];
CompilerEnvironmentAppendTo[env, {FunctionDeclaration[addTwo, Typed[{"Integer64"} -> "Integer64"]@Function[arg, 2arg]]}];Use a compiler environment in a compilation:
lib = FunctionCompileExportLibrary[ "functiondef.dylib", Function[{Typed[arg, "Integer64"]}, addTwo[arg]], CompilerEnvironment -> env];Loading the library creates a CompiledCodeFunction:
funs = LibraryFunctionLoad[lib]Execute the code that was loaded:
funs[10]ProgressReporting (1)
Progress during a compilation is reported:
FunctionCompileExportLibrary["mylib.dylib", Function[{Typed[s, "String"]}, ToCharacterCode[s]]]This can be suppressed by setting the option ProgressReporting to False.
The default value of ProgressReporting is Automatic, which means that the global setting $ProgressReporting is used. If this is set to False, then no progress reporting takes place.
Text
Wolfram Research (2019), FunctionCompileExportLibrary, Wolfram Language function, https://reference.wolfram.com/language/ref/FunctionCompileExportLibrary.html (updated 2021).
CMS
Wolfram Language. 2019. "FunctionCompileExportLibrary." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2021. https://reference.wolfram.com/language/ref/FunctionCompileExportLibrary.html.
APA
Wolfram Language. (2019). FunctionCompileExportLibrary. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/FunctionCompileExportLibrary.html