Sitelet https://reference.wolfram.com/language/ref/CompiledComponent.html

WOLFRAM

Wolfram Language & System Documentation Center

CompiledComponent[name]

represents a compiled component.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Possible Issues  
See Also
Tech Notes
Related Guides
History
Cite this Page

CompiledComponent

CompiledComponent[name]

represents a compiled component.

Details

  • Compiled components can be used to represent a named group of compiler declarations.
  • Compiled components can be used to represent compiled functionality that can be built into a shared library.
  • Compiled components can be embedded in paclets.
  • A compiled component is created by DeclareCompiledComponent.
  • CompiledComponent objects can be used to add declarations for compilation.
  • CompiledComponent objects can be used to discover details of a compiled component.
  • CompiledComponent objects can be cleared with DeleteObject. »
  • Fields of a compiled component can be accessed with CompiledComponent[name][field].
  • CompiledComponent[name][All] returns an association of all fields in the component.
  • Compiled components contain the following fields, which can be modified with DeclareCompiledComponent:
  • "Declarations"declarations to use with the component
    "InstalledFunctions"functions to compile and symbols into which to install the results
    "LibraryFunctions"functions to compile, to be recovered by LoadCompiledComponent
    "RawLibraryFunctions"functions to compile that are available as library exports
    "LoadingEpilogs"functions to be executed after the component is loaded by LoadCompiledComponent
    "ExternalLibraries"libraries to be loaded before the component is loaded by LoadCompiledComponent
  • The "InstalledFunctions" and "LibraryFunctions" fields contain the source to be compiled. BuildCompiledComponent builds that source and saves the result to a dynamic library. The dynamic library can be loaded with LoadCompiledComponent to recover the results of the compilation.

Examples

open all close all

Basic Examples  (2)

Create a compiled component "demo" containing a declaration:

Wolfram Language code: DeclareCompiledComponent["demo", FunctionDeclaration[square, Typed[{"Real64"} -> "Real64"]@Function[x, x ^ 2]]];

View the resulting component:

Wolfram Language code: CompiledComponent["demo"]

Use CompiledComponent in a call to FunctionCompile:

Wolfram Language code: comp = FunctionCompile[CompiledComponent["demo"], Function[Typed[arg, "Real64"], square[arg]]]
Wolfram Language code: comp[10]

Clear the component:

Wolfram Language code: DeleteObject[CompiledComponent["demo"]]

Create a compiled component:

Wolfram Language code: DeclareCompiledComponent["demo2", FunctionDeclaration[multiply12, Typed[{"Real64"} -> "Real64"]@Function[x, x * 12]]];

Use CompiledComponent to add declarations to the compiler environment:

Wolfram Language code: CompilerEnvironmentAppendTo[CompiledComponent["demo2"]];

Compile a program using a function from the component:

Wolfram Language code: comp = FunctionCompile[Function[Typed[arg, "Real64"], multiply12[arg]]]
Wolfram Language code: comp[10]

Scope  (1)

Declare a list of declarations in a component:

Wolfram Language code: DeclareCompiledComponent["fullComponent", { FunctionDeclaration[return12, Typed[{} -> "MachineInteger"]@Function[{}, 12]], FunctionDeclaration[addtwo, Typed[{"MachineInteger"} -> "MachineInteger"]@Function[x, x + 2]] }];

Declare a library function:

Wolfram Language code: DeclareCompiledComponent["fullComponent", "LibraryFunctions" -> <| "libFunc" -> Function[Typed[arg, "Real64"], Sqrt[arg]] |>];

Declare an installed function:

Wolfram Language code: DeclareCompiledComponent["fullComponent", "InstalledFunctions" -> addtwo];

Extract all properties of the component:

Wolfram Language code: CompiledComponent["fullComponent"][All]

Properties of a component:

Wolfram Language code: CompiledComponent["fullComponent"]["Properties"]

The declarations of a component:

Wolfram Language code: CompiledComponent["fullComponent"]["Declarations"]

Clear the component:

Wolfram Language code: DeleteObject[CompiledComponent["fullComponent"]]

Possible Issues  (1)

It is an error to refer to a component that has not been created:

Wolfram Language code: CompiledComponent["unknown"]
Wolfram Research (2022), CompiledComponent, Wolfram Language function, https://reference.wolfram.com/language/ref/CompiledComponent.html.

Text

Wolfram Research (2022), CompiledComponent, Wolfram Language function, https://reference.wolfram.com/language/ref/CompiledComponent.html.

CMS

Wolfram Language. 2022. "CompiledComponent." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/CompiledComponent.html.

APA

Wolfram Language. (2022). CompiledComponent. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CompiledComponent.html

BibTeX

@misc{reference.wolfram_2026_compiledcomponent, author="Wolfram Research", title="{CompiledComponent}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/CompiledComponent.html}", note=[Accessed: 05-October-2026]}

BibLaTeX

@online{reference.wolfram_2026_compiledcomponent, organization={Wolfram Research}, title={CompiledComponent}, year={2022}, url={https://reference.wolfram.com/language/ref/CompiledComponent.html}, note=[Accessed: 05-October-2026]}