Returns a list of all non-overlapping matches in the given string.

string is the string to find matches from and pattern is the regular expression. See the BuiltIn library keyword Should Match Regexp for more information about Python regular expression syntax in general and how to use it in Robot Framework data in particular.

If no groups are used, the returned list contains full matches. If one group is used, the list contains only contents of that group. If multiple groups are used, the list contains tuples that contain individual group contents. All groups can be given as indexes (starting from 1) and named groups can also be given as names.

Possible flags altering how the expression is parsed (e.g. re.IGNORECASE, re.MULTILINE) can be given using the flags argument (e.g. flags=IGNORECASE | MULTILINE) or embedded to the pattern (e.g. (?im)pattern).

Examples:

*** Variables ***
${string}        the string

*** Test Cases ***
No match
    ${result} =    Get Regexp Matches    ${string}    xxx
    Should Be Equal    ${result}    []    type=list

Match
    ${result} =    Get Regexp Matches    ${string}    t..
    Should Be Equal    ${result}    ["the", "tri"]    type=list

Flags
    ${result} =    Get Regexp Matches    ${string}    T..    flags=IGNORECASE
    Should Be Equal    ${result}    ["the", "tri"]    type=list

One group by index
    ${result} =    Get Regexp Matches    ${string}    t(..)    1
    Should Be Equal    ${result}    ["he", "ri"]    type=list

One group by name
    ${result} =    Get Regexp Matches    ${string}    t(?P<name>..)    name
    Should Be Equal    ${result}    ["he", "ri"]    type=list

Multiple groups
    ${result} =    Get Regexp Matches    ${string}    t(.)(.)    1    2
    Should Be Equal    ${result}    [("h", "e"), ("r", "i")]    type=list

If the first argument is bytes, the second argument is automatically converted to bytes as well. This is new in Robot Framework 7.4.

The flags argument is new in Robot Framework 6.0.

Opening library documentation failed