@echo OFF

set PythonExe=""

set PythonExeFlags=

for %%i in (cmd bat exe) do (

for %%j in (python.%%i) do (

call :SetPythonExe "%%~$PATH:j"

)

)

for /f "tokens=2 delims==" %%i in ('assoc .py') do (

for /f "tokens=2 delims==" %%j in ('ftype %%i') do (

for /f "tokens=1" %%k in ("%%j") do (

call :SetPythonExe %%k

)

)

)

%PythonExe% -x %PythonExeFlags% "%~f0" %*

exit /B %ERRORLEVEL%

goto :EOF

:SetPythonExe

if not ["%~1"]==[""] (

if [%PythonExe%]==[""] (

set PythonExe="%~1"

)

)

goto :EOF

# ===================================================

# Python script starts here

# ===================================================

#!/usr/bin/env python

# Copyright 2012 Amazon.com, Inc. or its affiliates. All Rights Reserved.

# Licensed under the Apache License, Version 2.0 (the "License"). You

# may not use this file except in compliance with the License. A copy of

# the License is located at

# http://aws.amazon.com/apache2.0/

# or in the "license" file accompanying this file. This file is

# distributed on an "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF

# ANY KIND, either express or implied. See the License for the specific

# language governing permissions and limitations under the License.

import awscli.clidriver

import sys

def main():

return awscli.clidriver.main()

if __name__ == '__main__':

sys.exit(main())